Cara Backup Mikrotik secara Otomatis kirim ke email

 

Berikut cara Backup settingan Mikrotik secara otomatis dengan Script pada Scheduler, dengan script ini maka mikrotik akan mengirim backup atas settingan mikrotik ke email anda dimana alamat emailnya dapat diubah pada baris Local Tujuan pada script dibawah,sesuai dengan jadwal dan interval waktu yang kita berikan pada menu Scheduler pada System Mikrotik, berikut scriptnya

#Script Autobackup Mikrotik ke Email V. 1 | OK
:local identity [/system identity get name];
#setting
:local tujuan "contoh12345@gmail.com";
:local subject "Backup Rutin Mikrotik $identity";
:local pesan " Email ini dikirim otomatis dari mikrotik $identity berisi file backup & export";


# Get Time
:local jam [:pick [/system clock get time] 0 2];
:local min [:pick [/system clock get time] 3 5];
:local dtk [:pick [/system clock get time] 6 8];
:local bln [:pick [/system clock get date] 0 3];
:local tgl [:pick [/system clock get date] 4 6];
:local thn [:pick [/system clock get date] 7 11];

# Set Filename
:local namafile "$identity_$tgl_$bln_$thn_$jam:$min:$dtk"

#Export
:delay 5s;
/export  file=$namafile
log warning ("SYSTEM Export DIJALANKAN Pada : $namafile");
:delay 25s;

#Backup
/system backup save dont-encrypt=yes name=$namafile
log warning ("SYSTEM BACKUP DIJALANKAN Pada : $namafile");
:delay 25s;


#Kirim Email
log warning ("mengirim email backup");
/tool e-mail send to=$tujuan subject=$subject body=$pesan file="$namafile.rsc,$namafile.backup"
:delay 90s;

#Hapus file temporary
:local namafilersc 
set namafilersc ($namafile . ".rsc")
:local namafilebackup
set namafilebackup ($namafile . ".backup")

/file remove $namafilersc
/file remove $namafilebackup

log warning ("menghapus temporary files");